Script DitDossierOuvert ()
;Ctrl +Maj +!
var handle hdReal , handle hdBD, handle hdWW, object o, string st, string st0, string st1, string st2
let hdReal  = GetRealWindow(GetFocus())
let hdWW = FindWindow(hdReal,"WorkerW","")
let hdBD= FindWindow(hdWW,"ReBarWindow32","")
let hdBD= FindWindow(hdBD,"Address Band Root","")
let hdBD= FindWindow(hdBD,"msctls_progress32","")
let hdBD= FindWindow(hdBD,"Breadcrumb Parent","")
let hdBD= FindWindow(hdBD,"ToolbarWindow32","")

;pour boite Ouvrir et Explorateur W7
If hdWW &&GetWindowClass(hdBD)=="ToolbarWindow32" then
	let o = GetObjectFromEvent(hdBD, -4 ,0 ,0)	
	var int iMax, int i, int j
	let iMax = o.accChildCount
	let st1 = o.accChild(iMax).accName(0)
	If st1=="" then
		let st2= o.accName(0)
		if StringContains(st2,"\\") 
			let st1= StringSegment(st2,"\\",-1) 
		Elif StringContains(st2,": ") 
			let st1= StringSegment(st2,"; ",-1)  
		EndIf
	EndIf
	If  iMax>1 then
		let st0 = o.accChild(iMax-1).accName(0)
	EndIf
	If st1!="" then
		let st ="Dossier ouvert, "+st1
	EndIf
	If st1!=""&&st0!="" then
		let st =st+", dans "+st0
	EndIf
	SayString(st)
	return
EndIf

if !(GetWindowName(hdReal)=="Ouvrir"
|| StringContains(GetWindowName(hdReal),"Enregistrer")
|| GetWindowName(hdReal)=="Chercher dans") then
	return
EndIf

;pour boites Office 2003
if StringContains(GetWindowClass(hdReal),"bosa_sdm_") then
	let o = GetObjectFromEvent(hdReal, -4 ,15 ,0)
	SayFormattedMessage (OT_message, FormatString("%1 , %2", o.accName(0), o.accValue(0)))
	return

;pour boites type XP
elIf GetControlID(FindWindow(hdReal,"SHELLDLL_DefView",""))==1121 then
	let o = GetObjectFromEvent(FindDescendantWindow(hdReal,1137),-4,0,0)
	SayFormattedMessage (OT_message, FormatString("%1 , %2", o.accName(0), o.accValue(0)))
EndIf
EndScript